Arduino内置教程-控制结构-Switch Case选择语句

简介

• 一个if声明允许你选择两个分开的选项，真或假。当有超过2个的选项，你可以用多个if声明，或者你可以用switch声明。switch允许你选择多个选项。这个教程示范怎样用它在四种光电阻的状态下切换开关：全黑，昏暗，中等，明亮。
• 这个程序首先读取光敏电阻。然后它用map（）函数来使它的输出值符合四个值之一：0，1，2，3。最后，用switch（）声明来打印对应的信息到电脑里。

硬件要求

• Arduino or Genuino开发板
• 光敏电阻, 或者 其他模拟传感器
• 10kΩ 电阻
• 连接线
• 面包板

电路

光敏电阻通过一个分压电路连接到模拟输入pin0。一个10k ohm电阻补充分压器的另一部分，从模拟输入pin0连到地。analogRead()函数从这个电路返回一个0-600的范围值。

原理图

样例代码

// these constants won't change. They are the
// lowest and highest readings you get from your sensor:
const int sensorMin = 0;      // sensor minimum, discovered through experiment
const int sensorMax = 600;    // sensor maximum, discovered through experiment

void setup() {
  // initialize serial communication:
  Serial.begin(9600);
}

void loop() {
  // read the sensor:
  int sensorReading = analogRead(A0);
  // map the sensor range to a range of four options:
  int range = map(sensorReading, sensorMin, sensorMax, 0, 3);

  // do something different depending on the
  // range value:
  switch (range) {
    case 0:    // your hand is on the sensor
      Serial.println("dark");
      break;
    case 1:    // your hand is close to the sensor
      Serial.println("dim");
      break;
    case 2:    // your hand is a few inches from the sensor
      Serial.println("medium");
      break;
    case 3:    // your hand is nowhere near the sensor
      Serial.println("bright");
      break;
  }
  delay(1);        // delay in between reads for stability
}